Operadores no Portugol

Os operadores são símbolos ou palavras usados para realizar ações com valores e variáveis em um programa. Com eles, podemos fazer cálculos, comparar informações e combinar condições.

Neste tópico, vamos conhecer três grupos de operadores muito usados no Portugol: os aritméticos, os de comparação e os lógicos.

Operadores Aritméticos

Os operadores aritméticos são usados para realizar cálculos matemáticos.

Operador	Descrição	Exemplo	Resultado
+	Soma dois valores.	2 + 3	5
-	Subtrai um valor de outro.	10 - 4	6
*	Multiplica dois valores.	5 * 2	10
/	Divide um valor por outro.	8 / 2	4
%	Retorna o resto da divisão inteira.	7 % 2	1

Por exemplo, se quisermos calcular a média de duas notas, podemos usar os operadores de soma e divisão:

inteiro nota1, nota2, media

nota1 = 8
nota2 = 6
media = (nota1 + nota2) / 2

escreva("A média é: ", media)

O operador % é útil quando queremos descobrir, por exemplo, se um número é par ou ímpar.

inteiro resto
resto = 7 % 2
escreva(resto)

Nesse caso, o valor exibido será 1, pois a divisão de 7 por 2 deixa resto 1.

Operadores de Comparação

Os operadores de comparação são usados para verificar a relação entre dois valores. O resultado de uma comparação sempre será um valor lógico, ou seja, verdadeiro ou falso.

Eles são muito utilizados quando queremos tomar decisões em um programa, como descobrir se uma nota é maior que outra, se dois valores são iguais ou se um número é diferente de outro.

Operador	Descrição	Exemplo
>	Verifica se um valor é maior que outro.	idade > 18
<	Verifica se um valor é menor que outro.	nota < 7
==	Verifica se dois valores são iguais.	numero == 10
>=	Verifica se um valor é maior ou igual a outro.	media >= 6
<=	Verifica se um valor é menor ou igual a outro.	faltas <= 10
!=	Verifica se dois valores são diferentes.	senha != 1234

Por exemplo, se quisermos verificar se um aluno foi aprovado com média igual ou superior a 6, podemos escrever:

media >= 6

Se o valor de media for 6 ou mais, o resultado dessa expressão será verdadeiro. Caso contrário, o resultado será falso.

Operadores de comparação podem ser utilizados para comparar números, textos e até mesmo valores lógicos. Por exemplo:

programa {
    funcao inicio() {
        inteiro temperatura
        logico esta_frio

        temperatura = 15
        esta_frio = (temperatura < 20)

        escreva("Está frio? ", esta_frio) // Saída: Está frio? verdadeiro
    }
}

programa {
    funcao inicio() {
        cadeia nome1, nome2
        nome1 = "João"
        nome2 = "Maria"

        logico nomes_iguais
        nomes_iguais = (nome1 == nome2)

        escreva("Os nomes são iguais? ", nomes_iguais) // Saída: Os nomes são iguais? falso
    }
}

Operadores Lógicos

Os operadores lógicos são usados para combinar expressões que resultam em verdadeiro ou falso.

Eles são úteis quando precisamos avaliar mais de uma condição ao mesmo tempo.

Operador	Descrição	Exemplo
e	Retorna verdadeiro quando as duas condições são verdadeiras.	idade >= 18 e idade < 60
ou	Retorna verdadeiro quando pelo menos uma condição é verdadeira.	nota >= 6 ou recuperacao == verdadeiro
nao	Inverte o valor lógico de uma expressão.	nao aluno_matriculado

Veja este exemplo:

idade >= 18 e idade < 60

Essa expressão só será verdadeira se as duas comparações forem verdadeiras ao mesmo tempo.

Veja outro exemplo:

nota >= 6 ou recuperacao == verdadeiro

Nesse caso, basta que uma das condições seja verdadeira para que o resultado final também seja verdadeiro.

Também podemos inverter um valor lógico com !:

logico valor = !aluno_matriculado

Se aluno_matriculado for verdadeiro, a expressão acima terá valor falso. Se for falso, o valor será verdadeiro.

Caracteres Especiais

Além dos operadores, existem alguns caracteres especiais que têm funções específicas em um programa. Toda vez que usamos um desses caracteres em um texto literal (entre aspas), o programa interpreta de uma forma diferente, realizando uma ação específica ao invés de simplesmente exibir o caractere.

Esses caracteres são chamados de caracteres de escape, e eles começam com uma barra invertida \. Veja a tabela abaixo com os principais caracteres de escape usados no Portugol:

Caractere	Descrição	Exemplo	Saída
\n	Quebra de linha.	escreva("Olá\nMundo")	Olá Mundo
\t	Tabulação.	escreva("Olá\tMundo")	Olá  Mundo
\\	Barra invertida.	escreva("C:\\Users\\João")	C:\Users\João

No caso do \n, a mensagem “Olá” será exibida em uma linha, e “Mundo” em outra linha. O \t adiciona um espaço maior entre as palavras, e o \\ é usado para mostrar uma barra invertida na saída, já que a barra invertida sozinha é interpretada como o início de um caractere de escape.